mirror of
https://https.git.savannah.gnu.org/git/gnulib.git
synced 2026-09-04 12:41:58 +00:00
Bruno Haible
95af6e04d9
* m4/chdir-long.m4 (gl_FUNC_CHDIR_LONG): Quote systematically. * m4/d-ino.m4 (gl_CHECK_TYPE_STRUCT_DIRENT_D_INO): Likewise. * m4/d-type.m4 (gl_CHECK_TYPE_STRUCT_DIRENT_D_TYPE): Likewise. * m4/dirfd.m4 (gl_FUNC_DIRFD): Likewise. * m4/host-os.m4 (gl_HOST_OS): Likewise. * m4/jm-winsz1.m4 (gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H, gl_WINSIZE_IN_PTEM): Likewise. * m4/mbrtowc.m4 (AC_FUNC_MBRTOWC): Likewise. * m4/physmem.m4 (gl_SYS__SYSTEM_CONFIGURATION): Likewise. * m4/pselect.m4 (gl_FUNC_PSELECT): Likewise. * m4/fchownat.m4 (gl_FUNC_FCHOWNAT_DEREF_BUG): Quote systematically. Correct indentation. * m4/getcwd-abort-bug.m4 (gl_FUNC_GETCWD_ABORT_BUG): Likewise. * m4/getcwd-path-max.m4 (gl_FUNC_GETCWD_PATH_MAX): Likewise. * m4/jm-winsz2.m4 (gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL): Likewise. * m4/rmdir-errno.m4 (gl_FUNC_RMDIR_NOTEMPTY): Likewise. * m4/tzset.m4 (gl_FUNC_TZSET_CLOBBER): Likewise. * m4/unlink-busy.m4 (gl_FUNC_UNLINK_BUSY_TEXT): Likewise.
71 lines
2.2 KiB
Plaintext
71 lines
2.2 KiB
Plaintext
# pselect.m4 serial 4
|
|
dnl Copyright (C) 2011-2017 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_FUNC_PSELECT],
|
|
[
|
|
AC_REQUIRE([gl_HEADER_SYS_SELECT])
|
|
AC_REQUIRE([AC_C_RESTRICT])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
AC_CHECK_FUNCS_ONCE([pselect])
|
|
|
|
if test $ac_cv_func_pselect = yes; then
|
|
AC_CACHE_CHECK([whether signature of pselect conforms to POSIX],
|
|
[gl_cv_sig_pselect],
|
|
[AC_LINK_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[[#include <sys/select.h>
|
|
]],
|
|
[[int (*p) (int, fd_set *, fd_set *, fd_set *restrict,
|
|
struct timespec const *restrict,
|
|
sigset_t const *restrict) = pselect;
|
|
return !p;]])],
|
|
[gl_cv_sig_pselect=yes],
|
|
[gl_cv_sig_pselect=no])])
|
|
|
|
dnl On FreeBSD 8.2, pselect() doesn't always reject bad fds.
|
|
AC_CACHE_CHECK([whether pselect detects invalid fds],
|
|
[gl_cv_func_pselect_detects_ebadf],
|
|
[
|
|
AC_RUN_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <sys/types.h>
|
|
#include <sys/time.h>
|
|
#if HAVE_SYS_SELECT_H
|
|
# include <sys/select.h>
|
|
#endif
|
|
#include <unistd.h>
|
|
#include <errno.h>
|
|
]],[[
|
|
fd_set set;
|
|
dup2(0, 16);
|
|
FD_ZERO(&set);
|
|
FD_SET(16, &set);
|
|
close(16);
|
|
struct timespec timeout;
|
|
timeout.tv_sec = 0;
|
|
timeout.tv_nsec = 5000;
|
|
return pselect (17, &set, NULL, NULL, &timeout, NULL) != -1 || errno != EBADF;
|
|
]])], [gl_cv_func_pselect_detects_ebadf=yes],
|
|
[gl_cv_func_pselect_detects_ebadf=no],
|
|
[
|
|
case "$host_os" in
|
|
# Guess yes on glibc systems.
|
|
*-gnu*) gl_cv_func_pselect_detects_ebadf="guessing yes" ;;
|
|
# If we don't know, assume the worst.
|
|
*) gl_cv_func_pselect_detects_ebadf="guessing no" ;;
|
|
esac
|
|
])
|
|
])
|
|
case $gl_cv_func_pselect_detects_ebadf in
|
|
*yes) ;;
|
|
*) REPLACE_PSELECT=1 ;;
|
|
esac
|
|
fi
|
|
|
|
if test $ac_cv_func_pselect = no || test $gl_cv_sig_pselect = no; then
|
|
REPLACE_PSELECT=1
|
|
fi
|
|
])
|