mirror of
https://https.git.savannah.gnu.org/git/gnulib.git
synced 2026-09-04 04:31:33 +00:00
Bruno Haible
3b1faeb2e2
* m4/argz.m4 (gl_FUNC_ARGZ): Require AC_CANONICAL_HOST. * m4/closedir.m4 (gl_FUNC_CLOSEDIR): Likewise. * m4/csharpexec.m4 (gt_CSHARPEXEC): Likewise. * m4/dirfd.m4 (gl_FUNC_DIRFD): Likewise. * m4/expl.m4 (gl_FUNC_EXPL): Likewise. * m4/ls-mntd-fs.m4 (gl_LIST_MOUNTED_FILE_SYSTEMS): Likewise. * m4/lstat.m4 (gl_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK): Likewise. * m4/opendir.m4 (gl_FUNC_OPENDIR): Likewise. * m4/poll.m4 (gl_FUNC_POLL): Likewise. * m4/pselect.m4 (gl_FUNC_PSELECT): Likewise. * m4/ptsname.m4 (gl_FUNC_PTSNAME): Likewise. * m4/relocatable.m4 (gl_RELOCATABLE_BODY): Likewise. * m4/symlinkat.m4 (gl_FUNC_SYMLINKAT): Likewise. * m4/ceill.m4 (gl_FUNC_CEILL): Require AC_CANONICAL_HOST outside the m4_ifdef block.
105 lines
3.2 KiB
Plaintext
105 lines
3.2 KiB
Plaintext
# poll.m4 serial 18
|
|
dnl Copyright (c) 2003, 2005-2007, 2009-2017 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_FUNC_POLL],
|
|
[
|
|
AC_REQUIRE([gl_POLL_H])
|
|
AC_REQUIRE([gl_SOCKETS])
|
|
AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
|
|
if test $ac_cv_header_poll_h = no; then
|
|
ac_cv_func_poll=no
|
|
gl_cv_func_poll=no
|
|
else
|
|
AC_CHECK_FUNC([poll],
|
|
[# Check whether poll() works on special files (like /dev/null) and
|
|
# and ttys (like /dev/tty). On Mac OS X 10.4.0 and AIX 5.3, it doesn't.
|
|
AC_RUN_IFELSE([AC_LANG_SOURCE([[
|
|
#include <fcntl.h>
|
|
#include <poll.h>
|
|
int main()
|
|
{
|
|
int result = 0;
|
|
struct pollfd ufd;
|
|
/* Try /dev/null for reading. */
|
|
ufd.fd = open ("/dev/null", O_RDONLY);
|
|
/* If /dev/null does not exist, it's not Mac OS X nor AIX. */
|
|
if (ufd.fd >= 0)
|
|
{
|
|
ufd.events = POLLIN;
|
|
ufd.revents = 0;
|
|
if (!(poll (&ufd, 1, 0) == 1 && ufd.revents == POLLIN))
|
|
result |= 1;
|
|
}
|
|
/* Try /dev/null for writing. */
|
|
ufd.fd = open ("/dev/null", O_WRONLY);
|
|
/* If /dev/null does not exist, it's not Mac OS X nor AIX. */
|
|
if (ufd.fd >= 0)
|
|
{
|
|
ufd.events = POLLOUT;
|
|
ufd.revents = 0;
|
|
if (!(poll (&ufd, 1, 0) == 1 && ufd.revents == POLLOUT))
|
|
result |= 2;
|
|
}
|
|
/* Trying /dev/tty may be too environment dependent. */
|
|
return result;
|
|
}]])],
|
|
[gl_cv_func_poll=yes],
|
|
[gl_cv_func_poll=no],
|
|
[# When cross-compiling, assume that poll() works everywhere except on
|
|
# Mac OS X or AIX, regardless of its version.
|
|
AC_EGREP_CPP([MacOSX], [
|
|
#if (defined(__APPLE__) && defined(__MACH__)) || defined(_AIX)
|
|
This is MacOSX or AIX
|
|
#endif
|
|
], [gl_cv_func_poll=no], [gl_cv_func_poll=yes])])])
|
|
fi
|
|
if test $gl_cv_func_poll != yes; then
|
|
AC_CHECK_FUNC([poll], [ac_cv_func_poll=yes], [ac_cv_func_poll=no])
|
|
if test $ac_cv_func_poll = no; then
|
|
HAVE_POLL=0
|
|
else
|
|
REPLACE_POLL=1
|
|
fi
|
|
fi
|
|
if test $HAVE_POLL = 0 || test $REPLACE_POLL = 1; then
|
|
:
|
|
else
|
|
AC_DEFINE([HAVE_POLL], [1],
|
|
[Define to 1 if you have the 'poll' function and it works.])
|
|
fi
|
|
|
|
dnl Determine the needed libraries.
|
|
LIB_POLL="$LIBSOCKET"
|
|
if test $HAVE_POLL = 0 || test $REPLACE_POLL = 1; then
|
|
case "$host_os" in
|
|
mingw*)
|
|
dnl On the MSVC platform, the function MsgWaitForMultipleObjects
|
|
dnl (used in lib/poll.c) requires linking with -luser32. On mingw,
|
|
dnl it is implicit.
|
|
AC_LINK_IFELSE(
|
|
[AC_LANG_SOURCE([[
|
|
#define WIN32_LEAN_AND_MEAN
|
|
#include <windows.h>
|
|
int
|
|
main ()
|
|
{
|
|
MsgWaitForMultipleObjects (0, NULL, 0, 0, 0);
|
|
return 0;
|
|
}]])],
|
|
[],
|
|
[LIB_POLL="$LIB_POLL -luser32"])
|
|
;;
|
|
esac
|
|
fi
|
|
AC_SUBST([LIB_POLL])
|
|
])
|
|
|
|
# Prerequisites of lib/poll.c.
|
|
AC_DEFUN([gl_PREREQ_POLL],
|
|
[
|
|
AC_CHECK_HEADERS_ONCE([sys/ioctl.h sys/filio.h])
|
|
])
|