mirror of
https://https.git.savannah.gnu.org/git/gnulib.git
synced 2026-09-06 05:31:48 +00:00
Bruno Haible
95af6e04d9
* m4/chdir-long.m4 (gl_FUNC_CHDIR_LONG): Quote systematically. * m4/d-ino.m4 (gl_CHECK_TYPE_STRUCT_DIRENT_D_INO): Likewise. * m4/d-type.m4 (gl_CHECK_TYPE_STRUCT_DIRENT_D_TYPE): Likewise. * m4/dirfd.m4 (gl_FUNC_DIRFD): Likewise. * m4/host-os.m4 (gl_HOST_OS): Likewise. * m4/jm-winsz1.m4 (gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H, gl_WINSIZE_IN_PTEM): Likewise. * m4/mbrtowc.m4 (AC_FUNC_MBRTOWC): Likewise. * m4/physmem.m4 (gl_SYS__SYSTEM_CONFIGURATION): Likewise. * m4/pselect.m4 (gl_FUNC_PSELECT): Likewise. * m4/fchownat.m4 (gl_FUNC_FCHOWNAT_DEREF_BUG): Quote systematically. Correct indentation. * m4/getcwd-abort-bug.m4 (gl_FUNC_GETCWD_ABORT_BUG): Likewise. * m4/getcwd-path-max.m4 (gl_FUNC_GETCWD_PATH_MAX): Likewise. * m4/jm-winsz2.m4 (gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL): Likewise. * m4/rmdir-errno.m4 (gl_FUNC_RMDIR_NOTEMPTY): Likewise. * m4/tzset.m4 (gl_FUNC_TZSET_CLOBBER): Likewise. * m4/unlink-busy.m4 (gl_FUNC_UNLINK_BUSY_TEXT): Likewise.
84 lines
2.9 KiB
Plaintext
84 lines
2.9 KiB
Plaintext
# serial 10
|
|
|
|
# Copyright (C) 2001, 2003-2004, 2006, 2009-2017 Free Software Foundation, Inc.
|
|
# This file is free software; the Free Software Foundation
|
|
# gives unlimited permission to copy and/or distribute it,
|
|
# with or without modifications, as long as this notice is preserved.
|
|
|
|
# Written by Paul Eggert.
|
|
|
|
dnl From Paul Eggert.
|
|
|
|
# Define HOST_OPERATING_SYSTEM to a name for the host operating system.
|
|
AC_DEFUN([gl_HOST_OS],
|
|
[
|
|
AC_REQUIRE([AC_CANONICAL_HOST])dnl
|
|
AC_CACHE_CHECK([host operating system],
|
|
[gl_cv_host_operating_system],
|
|
|
|
[[case $host_os in
|
|
|
|
# These operating system names do not use the default heuristic below.
|
|
# They are in reverse order, so that more-specific prefixes come first.
|
|
winnt*) os='Windows NT';;
|
|
vos*) os='VOS';;
|
|
sysv*) os='Unix System V';;
|
|
superux*) os='SUPER-UX';;
|
|
sunos*) os='SunOS';;
|
|
stop*) os='STOP';;
|
|
sco*) os='SCO Unix';;
|
|
riscos*) os='RISC OS';;
|
|
riscix*) os='RISCiX';;
|
|
qnx*) os='QNX';;
|
|
pw32*) os='PW32';;
|
|
ptx*) os='ptx';;
|
|
plan9*) os='Plan 9';;
|
|
osf*) os='Tru64';;
|
|
os2*) os='OS/2';;
|
|
openbsd*) os='OpenBSD';;
|
|
nsk*) os='NonStop Kernel';;
|
|
nonstopux*) os='NonStop-UX';;
|
|
netbsd*-gnu*) os='GNU/NetBSD';; # NetBSD kernel+libc, GNU userland
|
|
netbsd*) os='NetBSD';;
|
|
mirbsd*) os='MirBSD';;
|
|
knetbsd*-gnu) os='GNU/kNetBSD';; # NetBSD kernel, GNU libc+userland
|
|
kfreebsd*-gnu) os='GNU/kFreeBSD';; # FreeBSD kernel, GNU libc+userland
|
|
msdosdjgpp*) os='DJGPP';;
|
|
mpeix*) os='MPE/iX';;
|
|
mint*) os='MiNT';;
|
|
mingw*) os='MinGW';;
|
|
lynxos*) os='LynxOS';;
|
|
linux*) os='GNU/Linux';;
|
|
hpux*) os='HP-UX';;
|
|
hiux*) os='HI-UX';;
|
|
gnu*) os='GNU';;
|
|
freebsd*) os='FreeBSD';;
|
|
dgux*) os='DG/UX';;
|
|
bsdi*) os='BSD/OS';;
|
|
bsd*) os='BSD';;
|
|
beos*) os='BeOS';;
|
|
aux*) os='A/UX';;
|
|
atheos*) os='AtheOS';;
|
|
amigaos*) os='Amiga OS';;
|
|
aix*) os='AIX';;
|
|
|
|
# The default heuristic takes the initial alphabetic string
|
|
# from $host_os, but capitalizes its first letter.
|
|
[A-Za-z]*)
|
|
os=`
|
|
expr "X$host_os" : 'X\([A-Za-z]\)' | LC_ALL=C tr '[a-z]' '[A-Z]'
|
|
``
|
|
expr "X$host_os" : 'X.\([A-Za-z]*\)'
|
|
`
|
|
;;
|
|
|
|
# If $host_os does not start with an alphabetic string, use it unchanged.
|
|
*)
|
|
os=$host_os;;
|
|
esac
|
|
gl_cv_host_operating_system=$os]])
|
|
AC_DEFINE_UNQUOTED([HOST_OPERATING_SYSTEM],
|
|
"$gl_cv_host_operating_system",
|
|
[The host operating system.])
|
|
])
|