mirror of
https://https.git.savannah.gnu.org/git/gnulib.git
synced 2026-09-03 20:21:35 +00:00
Bruno Haible
95af6e04d9
* m4/chdir-long.m4 (gl_FUNC_CHDIR_LONG): Quote systematically. * m4/d-ino.m4 (gl_CHECK_TYPE_STRUCT_DIRENT_D_INO): Likewise. * m4/d-type.m4 (gl_CHECK_TYPE_STRUCT_DIRENT_D_TYPE): Likewise. * m4/dirfd.m4 (gl_FUNC_DIRFD): Likewise. * m4/host-os.m4 (gl_HOST_OS): Likewise. * m4/jm-winsz1.m4 (gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H, gl_WINSIZE_IN_PTEM): Likewise. * m4/mbrtowc.m4 (AC_FUNC_MBRTOWC): Likewise. * m4/physmem.m4 (gl_SYS__SYSTEM_CONFIGURATION): Likewise. * m4/pselect.m4 (gl_FUNC_PSELECT): Likewise. * m4/fchownat.m4 (gl_FUNC_FCHOWNAT_DEREF_BUG): Quote systematically. Correct indentation. * m4/getcwd-abort-bug.m4 (gl_FUNC_GETCWD_ABORT_BUG): Likewise. * m4/getcwd-path-max.m4 (gl_FUNC_GETCWD_PATH_MAX): Likewise. * m4/jm-winsz2.m4 (gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL): Likewise. * m4/rmdir-errno.m4 (gl_FUNC_RMDIR_NOTEMPTY): Likewise. * m4/tzset.m4 (gl_FUNC_TZSET_CLOBBER): Likewise. * m4/unlink-busy.m4 (gl_FUNC_UNLINK_BUSY_TEXT): Likewise.
47 lines
1.7 KiB
Plaintext
47 lines
1.7 KiB
Plaintext
# physmem.m4 serial 12
|
|
dnl Copyright (C) 2002-2003, 2005-2006, 2008-2017 Free Software Foundation,
|
|
dnl Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
# Check for the external symbol, _system_configuration,
|
|
# a struct with member 'physmem'.
|
|
AC_DEFUN([gl_SYS__SYSTEM_CONFIGURATION],
|
|
[AC_CACHE_CHECK([for external symbol _system_configuration],
|
|
[gl_cv_var__system_configuration],
|
|
[AC_LINK_IFELSE([AC_LANG_PROGRAM(
|
|
[[#include <sys/systemcfg.h>
|
|
]],
|
|
[[double x = _system_configuration.physmem;
|
|
if (x > 0.0) return 0;]])],
|
|
[gl_cv_var__system_configuration=yes],
|
|
[gl_cv_var__system_configuration=no])])
|
|
|
|
if test $gl_cv_var__system_configuration = yes; then
|
|
AC_DEFINE([HAVE__SYSTEM_CONFIGURATION], [1],
|
|
[Define to 1 if you have the external variable,
|
|
_system_configuration with a member named physmem.])
|
|
fi
|
|
]
|
|
)
|
|
|
|
AC_DEFUN([gl_PHYSMEM],
|
|
[
|
|
# Prerequisites of lib/physmem.c.
|
|
AC_CHECK_HEADERS([sys/pstat.h sys/sysmp.h sys/sysinfo.h \
|
|
machine/hal_sysinfo.h sys/table.h sys/param.h sys/systemcfg.h],,,
|
|
[AC_INCLUDES_DEFAULT])
|
|
dnl <sys/sysctl.h> requires <sys/param.h> on OpenBSD 4.0.
|
|
AC_CHECK_HEADERS([sys/sysctl.h],,,
|
|
[AC_INCLUDES_DEFAULT
|
|
#if HAVE_SYS_PARAM_H
|
|
# include <sys/param.h>
|
|
#endif
|
|
])
|
|
|
|
AC_CHECK_FUNCS([pstat_getstatic pstat_getdynamic sysmp getsysinfo sysctl table sysinfo])
|
|
AC_CHECK_MEMBERS([struct sysinfo.mem_unit],,, [[#include <sys/sysinfo.h>]])
|
|
AC_REQUIRE([gl_SYS__SYSTEM_CONFIGURATION])
|
|
])
|